dwa buttony jako jeden... i inne problemy noob'a

Technologia Flash, czyli animacja na potrzeby stron WWW to świat daleko odbiegły od zwykłego programowania i kodu. Zapytaj o pomoc i podziel się z nami Twoimi problemami z zakresu Flasha.
nothing
Posty: 12
Rejestracja: wt cze 26, 2007 12:41 am

dwa buttony jako jeden... i inne problemy noob'a

Post autor: nothing »

witam!

mam problem. z pewnością banalny. sam to wiem, jednak nie mogę sobie poradzić, ani znaleźć rozwiązania. sytuację przedstawię tak:

mam dwa MC, oba po tyle samo klatek. oba identyczne. jeden i drugi służą za buttony. chcę by po najechaniu na pierwszy, uruchamiała się animacja drugiego. i vice versa.

normalnie po najechaniu na MC1, ten się animuje. gdy zjadę, animacja wraca do punktu wyjścia. z MC2 jest tak samo. tylko jak zrobić by były połączone i jeden oddziaływał na drugi?

nie mogę sobie poradzić z AS, proszę o pomoc

pozdrawiam!


EDIT:
zapomniałem podać kod. z pewnością będzi potrzebny. kod nie jest mojego autorstwa a jedynie 'zapożyczyłem' go z jednego z kursów dostępnych w sieci. no, skoro sumienie mam czyste... prosze:

Kod: Zaznacz cały

mc1.onRollOver = function() {
this.onEnterFrame = function() {
if (this._currentframe<10) {
this.nextFrame();
}
};
};
mc1.onRollOut = function() {
this.onEnterFrame = function() {
if (this._currentframe>0) {
this.prevFrame();
}
};
}

// powyższe linijki sprawiają jedynie by po najechaniu włączyła się animacja, 
// a po zjechaniu myszki, płynnie cofała się do punktu wyjścia. 
// tak samo wygląda kod dla mc2 oprócz innego instance name
Ostatnio zmieniony czw cze 28, 2007 3:21 pm przez nothing, łącznie zmieniany 1 raz.
nothing
Posty: 12
Rejestracja: wt cze 26, 2007 12:41 am

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: nothing »

ok. poradziłem sobie. wiem że taki efekt jest dość często używany. na moje potrzeby wystarczyło tylko by po najechaniu na mc1 uruchamiał się mc2, nie potrzeba już vice versa :] (łatwo dodać taki efekt, więc nie będę już tego robił).

po kolei...
najeżdżam myszą na mc1 - animacja rusza w mc1 i mc2
gdy zjeżdżam myszą z mc1 - animacja się cofa w mc1, także w mc2.

zostawiam kod dla potomnych, a nuż się przyda:

Kod: Zaznacz cały

mc1.onRollOver = function() {
this.onEnterFrame = function() {
if (this._currentframe<10) {
this.nextFrame();
}
};
mc2.onEnterFrame = function() {
if (mc2._currentframe<10) {
mc2.nextFrame();
};
};
};


mc1.onRollOut = function() {
this.onEnterFrame = function() {
if (this._currentframe>0) {
this.prevFrame();
}
};
mc2.onEnterFrame = function() {
if (mc2._currentframe>0) {
mc2.prevFrame();
};
};
};
Marek_bf
Administrator
Posty: 4419
Rejestracja: czw lut 24, 2005 2:14 am
Kontakt:

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: Marek_bf »

A jak będzie 10 buttonów?
nothing
Posty: 12
Rejestracja: wt cze 26, 2007 12:41 am

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: nothing »

Marek_bf pisze:A jak będzie 10 buttonów?
po pierwsze: z pewnością Ty wiesz dobrze jak to zrobić :>
po drugie: kto będzie chciał 10 buttonów uruchamianych jednym?
po trzecie: gdybym chciał te 10 to pewnie bym robił zagnieżdżenia zagnieżdżeń, co w efekcie było by bardzo nieczytelne i zajmowało by spory kawałek kodu. może za jakiś czas wpadnę na pomysł (może funkcje i tablice?). teraz jeszcze jestem za bardzo noobem i na prawdę nie mam pomysłu. nad flashem siedzę od wczorajszego popołudnia, będzie z 15h, wiec dużo nie potrafię

pozdrawiam!

ps. jeżeli możesz to wyjaśnij jak poprawnie ułożyć ten kod
Marek_bf
Administrator
Posty: 4419
Rejestracja: czw lut 24, 2005 2:14 am
Kontakt:

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: Marek_bf »

nothing pisze:po drugie: kto będzie chciał 10 buttonów uruchamianych jednym?
A dwa? Po co? To waśnie mnie zastanowiło. Na początku nie bardzo mogłem znaleźć zastosowanie. Ale po namyśle doszedłem do tego, że jednak może takie być. Chcąc np. pokazać w danej chwili zależne pogrupowane przyciski czy po prostu obiekty, w jakiejś gierce czy innej interaktywnej aplikacji.

Masz rację tablice, funkcje, pętle.
Ja bym to zrobił tak:

Kod: Zaznacz cały

var mc_arr:Array = [mc1, mc2, mc3, mc4];
var oef_mc:MovieClip = this.createEmptyMovieClip("oef_mc", this.getNextHighestDepth());
for (var i = 0; i < mc_arr.length; i++) {
	if (mc_arr[i] instanceof MovieClip) {
		mc_arr[i].stop();
		mc_arr[i].onRollOver = function() {
			foo(this, oef_mc, "nextFrame", mc_arr);
		};
		mc_arr[i].onRollOut = mc_arr[i].onDragOut = function () {
			foo(this, oef_mc, "prevFrame", mc_arr);
		};
	}
}
function foo(mc:MovieClip, ster_mc:MovieClip, prop:String, mc_arr:Array):Void {
	ster_mc.onEnterFrame = function() {
		if (prop == "nextFrame") {
			if (mc._currentframe != mc._totalframes) {
				for (var i = 0; i < mc_arr.length; i++) {
					mc_arr[i][prop]();
				}
			} else if (mc._currentframe == mc._totalframes) {
				delete this.onEnterFrame;
			}
		}
		if (prop == "prevFrame") {
			if (mc._currentframe != 1) {
				for (var i = 0; i < mc_arr.length; i++) {
					mc_arr[i][prop]();
				}
			} else if (mc._currentframe == 1) {
				delete this.onEnterFrame;
			}
		}
	};
}
nothing
Posty: 12
Rejestracja: wt cze 26, 2007 12:41 am

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: nothing »

Marek_bf pisze:
nothing pisze:po drugie: kto będzie chciał 10 buttonów uruchamianych jednym?
A dwa? Po co? To waśnie mnie zastanowiło. Na początku nie bardzo mogłem znaleźć zastosowanie. Ale po namyśle doszedłem do tego, że jednak może takie być. Chcąc np. pokazać w danej chwili zależne pogrupowane przyciski czy po prostu obiekty, w jakiejś gierce czy innej interaktywnej aplikacji.
[/code]
napisałem 2 buttony tylko po to żeby się nie rozpisywać o co mi chodzi. w rzeczywistości chciałem połączyć 2 różne animacje w jeden button. w końcu z dwóch mc złożyłem jeden. jednak takie majsterkowanie przy AS bardzo się przydaje.

dziękuje za napisanie kodu. nie rozumiem go do końca, muszę poznać więcej instrukcji charakterystycznych dla AS. jednak kod się przyda, chociażby dla chwili (raczej długiej) zastanowienia.

dzięki,
pozdrawiam!
nothing

ps. fajnie że szybko dostałem odpowiedzi. przyjazne forum
nothing
Posty: 12
Rejestracja: wt cze 26, 2007 12:41 am

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: nothing »

skoro założyłem wątek i wiem że mogę liczyć na odpowiedzi to będę Was teraz męczył i frustrował dopóki sobie palców nie połamię :]

a tak na serio... mam mały problem. spójrzcie na kod pewnego MC złożonego z 10. klatek:
on(rollOver) {
if (_currentframe<10) {
nextFrame();
}
}

otóż po najechaniu na MC, owe MC przechodzi do klatki nr. 2. gdy zjadę z MC i wjadę z powrotem, MC przechodzi do klatki 3. itd...

tak samo jest gdy wywołuję działanie MC poprzez wklepanie kodu w klatkę:
mc.onRollOver = function() {
if (this._currentframe<10) {
this.nextFrame();
}
};
dlaczego po najechaniu na MC kod się nie zapętla, tzn. nie przechodzi płynnie do 10. klatki, a jedynie skacze co 1. klatkę i to po ponownym najechaniu na MC? przecież _currentFrame jest ciągle mniejszy od 10 i MC powinien ciągle sunąć do przodu
natomiast gdy użyję takiego kodu w klatce, to wszystko gra jak Janko Muzykant:
mc.onRollOver = function() {
this.onEnterFrame = function() {
if (this._currentframe<10) {
this.nextFrame();
}
};
};
nie chcę używać this.onEnterFrame = function() gdyż wyczytałem że to spowalnia wykonywanie kodu. wyczytałem też, że można się obejść bez tej linijki, tylko nie wiem jak. poza tym nie bardzo rozumiem tego zdarzenia. czytałem help'a (za trudny poziom językowy jak dla mnie), szukałem w sieci, lecz nadal nie mogę dobrze tego zdarzenia zrozumieć, więc proszę o wyjaśnienie


i druga sprawa. czy istnieje jakiś sposób by poniższy kod wykonać od tyłu, tzn czy można sprawić, że będzie odgrywany od końca do początku?
mc.gotoAndPlay(1);

mam nadzieję że uzyskam choć część odpowiedzi. domyślam się że podobne problemy były już niejednokrotnie opisywane, lecz nie mogę odnaleźć rozwiązań. naprawdę staram się samodzielnie znaleźć odpowiedzi na nurtujące mnie pytania, lecz czasem po prostu muszę zwrócić się do kogoś o pomoc. proszę o wyrozumiałość.

pozdrawiam
Marek_bf
Administrator
Posty: 4419
Rejestracja: czw lut 24, 2005 2:14 am
Kontakt:

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: Marek_bf »

onRollOver to jest zdarzenie czyli kod wykonuje się wtedy gdy ono zachodzi, a nie sekwencyjnie. Dlatego właśnie trzeba użyć albo onEnterFrame albo setInterval.

onEnterFrame to po prostu zdarzenie wykonywane z prędkością równa prędkości odtwarzania filmu. Wszystko, co jest w ciele jego funkcji wykona się raz na klatkę.

oEF jak każda inna funkcja obciąża system w zależności od tego co dzieje się w jej ciele. Jeżeli masz ją zastosować do wielu obiektów lub prowadzić w niej skomplikowane obliczenia to fakt, najlepszy procesor można położyć.

Jednak chcąc uzyskać np. płynne przemieszczanie nie unikniesz oEF

Stworzymy sobie 475 mc i każdemu uruchomimy oEF.

Kod: Zaznacz cały

 var my_mc:MovieClip;
//
fps(this);
//
for (var i = 0; i < 25; i++) {
	for (var j = 0; j < 19; j++) {
		my_mc = draw_mc(this);
		my_mc._x = 20 * i + 40;
		my_mc._y = 20 * j + 20;
		my_mc.onEnterFrame = function() {
		};
	}
	
}
trace(i*j)
//
function fps(mc:MovieClip):Void {
	var fps:Number;
	var start_time:Number = getTimer();
	mc.createTextField("my_txt", mc.getNextHighestDepth(), 10, 10, 30, 22);
	mc.onEnterFrame = function() {
		fps = int(1000 / (getTimer() - start_time));
		this.my_txt.text = fps;
		start_time = getTimer();
	};
}
function draw_mc(mc:MovieClip):MovieClip {
	var mc:MovieClip = mc.createEmptyMovieClip("mc" + mc.getNextHighestDepth(), mc.getNextHighestDepth());
	mc.lineStyle(0);
	mc.beginFill(0x000000, 100);
	mc.moveTo(-5, -5);
	mc.lineTo(10, -5);
	mc.lineTo(10, 10);
	mc.lineTo(-5, 10);
	mc.lineTo(-5, -5);
	mc.endFill();
	return mc;
}
Jak widać na liczniku obok, ilość klatek na sekundę nie spada, więc i obciążenie jest niewielkie. (zależne od komputera).

A teraz to samo tylko dodamy obliczenia:

Kod: Zaznacz cały

 var my_mc:MovieClip;
//
fps(this);
//
for (var i = 0; i < 25; i++) {
	for (var j = 0; j < 19; j++) {
		my_mc = draw_mc(this);
		my_mc._x = 20 * i + 40;
		my_mc._y = 20 * j + 20;
		my_mc.onEnterFrame = function() {
			this._rotation += Math.round(Math.random() * 200) < 100 ? -5 : 5;
			this._alpha = Math.round(Math.random() * 200) < 100 ? 50 : 100;
		};
	}
	
}
trace(i*j)
//
function fps(mc:MovieClip):Void {
	var fps:Number;
	var start_time:Number = getTimer();
	mc.createTextField("my_txt", mc.getNextHighestDepth(), 10, 10, 30, 22);
	mc.onEnterFrame = function() {
		fps = int(1000 / (getTimer() - start_time));
		this.my_txt.text = fps;
		start_time = getTimer();
	};
}
function draw_mc(mc:MovieClip):MovieClip {
	var mc:MovieClip = mc.createEmptyMovieClip("mc" + mc.getNextHighestDepth(), mc.getNextHighestDepth());
	mc.lineStyle(0);
	mc.beginFill(0x000000, 100);
	mc.moveTo(-5, -5);
	mc.lineTo(10, -5);
	mc.lineTo(10, 10);
	mc.lineTo(-5, 10);
	mc.lineTo(-5, -5);
	mc.endFill();
	return mc;
}
Tutaj już widać zwis systemu, po spadku ilości klatek na sekundę. FlashPlayer nie tylko musi przeprowadzić obliczenia ale i wyświetlić zmiany na ekranie.

Nawet, jeżeli zrobimy tylko jeden główny oEF sytuacja się nie zmieni:

Kod: Zaznacz cały

 var my_mc:MovieClip;
var mc_arr:Array = [];
//
fps(this);
//
for (var i = 0; i < 25; i++) {
	for (var j = 0; j < 19; j++) {
		my_mc = draw_mc(this);
		my_mc._x = 20 * i + 40;
		my_mc._y = 20 * j + 20;
		mc_arr.push(my_mc);
	}
}
trace(i * j);
this.onEnterFrame = function() {
	for (var i = 0; i < mc_arr.length; i++) {
		mc_arr[i]._rotation += Math.round(Math.random() * 200) < 100 ? -5 : 5;
		mc_arr[i]._alpha = Math.round(Math.random() * 200) < 100 ? 50 : 100;
	}
};
//
function fps(mc:MovieClip):Void {
	var mc2:MovieClip = mc.createEmptyMovieClip("mc2", mc.getNextHighestDepth());
	var fps:Number;
	var start_time:Number = getTimer();
	mc.mc2.createTextField("my_txt", mc.getNextHighestDepth(), 10, 10, 30, 22);
	mc.mc2.onEnterFrame = function() {
		fps = int(1000 / (getTimer() - start_time));
		this.my_txt.text = fps;
		start_time = getTimer();
	};
}
function draw_mc(mc:MovieClip):MovieClip {
	var mc:MovieClip = mc.createEmptyMovieClip("mc" + mc.getNextHighestDepth(), mc.getNextHighestDepth());
	mc.lineStyle(0);
	mc.beginFill(0x000000, 100);
	mc.moveTo(-5, -5);
	mc.lineTo(10, -5);
	mc.lineTo(10, 10);
	mc.lineTo(-5, 10);
	mc.lineTo(-5, -5);
	mc.endFill();
	return mc;
}
Będzie on i tak musiał przeprowadzić obliczenia dla każdego mc osobno.

Również jeden oEF dla jednego MC może przy dyżej ilości czynności położyć system:

Kod: Zaznacz cały

 var my_mc:MovieClip;
//
fps(this);
//
my_mc = draw_mc(this);
//
function fps(mc:MovieClip):Void {
	var fps:Number;
	var start_time:Number = getTimer();
	mc.createTextField("my_txt", mc.getNextHighestDepth(), 10, 10, 30, 22);
	mc.onEnterFrame = function() {
		fps = int(1000 / (getTimer() - start_time));
		this.my_txt.text = fps;
		start_time = getTimer();
	};
}
function draw_mc(mc:MovieClip):MovieClip {
	var mc:MovieClip = mc.createEmptyMovieClip("mc" + mc.getNextHighestDepth(), mc.getNextHighestDepth());
	mc.onEnterFrame = function() {
		mc.clear();
		for (var i = 0; i < 100; i++) {
			mc.lineStyle(Math.round(Math.random() * 50), Math.round(Math.random() * 16777215), Math.round(Math.random() * 100));
			mc.moveTo(Math.random() * 550, 10 + Math.random() * 400);
			mc.lineTo(Math.random() * 550, 10 + Math.random() * 400);
		}
	};
	return mc;
}
Dlatego trzeba z niego korzystać umiarkowanie i wyłączać, kiedy nie jest potrzebny.

Jak cofać animację:
http://forum.webinside.pl/viewtopic.php ... ht=cofanie

Przyjrzyj się w tym przykładzie właśnie jest zastosowane wyłączanie oEF wtedy gdy nie jest on potrzebny, zresztą to samo jest w moim poście o włączaniu animacji kilku buttonów.

P.S. Dla oddzielnych problemów zakładaj nowe watki, później ktoś będzie mógł łatwiej je odszukać i z nich skorzystać.
Ostatnio zmieniony czw cze 28, 2007 6:59 pm przez Marek_bf, łącznie zmieniany 1 raz.
nothing
Posty: 12
Rejestracja: wt cze 26, 2007 12:41 am

Re: dwa buttony jako jeden... i inne problemy noob'a

Post autor: nothing »

dziękuję!

przede wszystkim za link. bardzo się przyda. poprzednie pytania są w zasadzie nieaktualne ponieważ to co jest w linku w zupełności wystarczy. przynajmniej na razie. jeżeli nie, to zrobię jak napisałeś - założę nowe wątki.
co do twojego opisu nt. oEF to nie do końca wszystko rozumiem, ale będę to jeszcze niejednokrotnie analizował. widzę, że starałeś się wszytko w miarę prosto, na ile to możliwe, przełożyć dla takiego zielonego jak ja. no i dodatkowo ten unaoczniający wszystko kod [choć także zrozumiały do pewnego stopnia. nadrobię wiedzę i będzie dobrze :] pełny profesjonalizm.

raz jeszcze dzięki
ODPOWIEDZ