wolno działający skrypt

Technologia Flash, czyli animacja na potrzeby stron WWW to świat daleko odbiegły od zwykłego programowania i kodu. Zapytaj o pomoc i podziel się z nami Twoimi problemami z zakresu Flasha.
nrb
Nowy
Nowy
Posty: 38
Rejestracja: sob kwie 30, 2005 3:37 pm
Kontakt:

wolno działający skrypt

Post autor: nrb »

Mam banalny problem, jednakze nie wiem (nie mam czasu dochodzic dlaczego :]) do konca dlaczego tak sie dzieje, otoz mam skrypcik zmieniajacy ._alpha obiektu:

Kod: Zaznacz cały

this.onRollOver = function() {
	nad = true;
	this.useHandCursor = false;
};
this.onRollOut = function() {
	nad = false;
};
if (nad == true) {
	white._alpha -= 10;
} else {
	white._alpha += 10;
}
..umieszczony w drugiej klatce (w pierwszej ustawiam domyslna wartosc zmiennej "nad" a w trzeciej, wiadomo, goToAndPlay(2); )

wszystko niby dziala ale jakos "wolno reaguje" tzn mc zaczyna zanikac dopiero po chwili od chwili gdy 'najade' na niego i odwrotnie(onRollOut)
Czasami nawet wcale nie dziala.

Co zrobic zeby przyspieszyc "reakcje", bo nie chce recznie tworzyc animacji zanikajacego mc i odtwarzac go po najechaniu mysza.
Marek_bf
Administrator
Posty: 4419
Rejestracja: czw lut 24, 2005 2:14 am
Kontakt:

Re: wolno działający skrypt

Post autor: Marek_bf »

Główny błąd u Ciebie jest taki, że nie masz ustalonych minimalnych i maksymalnych wartości _alpha możliwych do osiągnięcia.
Przy wartości zmiennej nad = true wartość _alpha może osiągnąć dowolnie dużą liczbę ujemna, co za ty idzie przy nad = false zmniejszanie przezroczystości zaczyna się od tej ujemnej liczby, co za tym idzie efekt nie będzie widoczny zanim alpha nie będzie większe od zera.
Podobnie jest, gdy zwiększasz wartość alpha w zależności od czasu trzymania kursora nad przyciskiem _alpha może przyjąć nieskończenie wielką wartość, ale widoczność efektu będzie tylko w zakresie 0 – 100.

Lepiej jest tak:

Kod: Zaznacz cały

// ustalamy poczatkowe wartości
var MC:MovieClip = white; // przypisuje movieclip
var propErties:String = "_alpha"; // na jakiej wlasciwosci
var propThis:Number = 100; // popczatkowa wartosc
var propMax:Number = propThis; //max wartosc domyslnie jak poczatkowa
var propMin:Number = 0; // min wartosc
var propSpeed:Number = 10; // szybkosc
MC[propErties] = propThis; // przypisuje poczatkowa watosc wlasciwosci do mc
// funkcja "malejaca"
function _propDown():Void {
	MC.onEnterFrame = function() {
		if (propThis > propMin) {
			propThis -= propSpeed;
		} else {
			propThis = propMin;
			delete this.onEnterFrame;
		}
		this[propErties] = propThis;
	};
}
// funkcja "rosnaca"
function _propUp():Void {
	MC.onEnterFrame = function() {
		if (propThis < propMax) {
			propThis += propSpeed;
		} else {
			propThis = propMax;
			delete this.onEnterFrame;
		}
		this[propErties] = propThis;
	};
}
// przypisujemy funkcje do odpowiednich uchwytow zdarzen buttonow
btn_mc.useHandCursor = false;
btn_mc.onRollOver = _propDown;
btn_mc.onRollOut = _propUp;
btn_mc.onDragOut = btn_mc.onRollOut;
Ostatnio zmieniony ndz wrz 25, 2005 3:28 pm przez Marek_bf, łącznie zmieniany 1 raz.
nrb
Nowy
Nowy
Posty: 38
Rejestracja: sob kwie 30, 2005 3:37 pm
Kontakt:

Re: wolno działający skrypt

Post autor: nrb »

Aha, rozumiem. Ja po prostu myslalem ze wartoc _alpha moze przybierac wartosci tylko z zakresu od 0 do 100 i dlatego nie okreslalem granicznych wartosci bedac przekonanym ze gdy np. _alpha osiagnie 0 to dalej juz nie bedzie sie zmniejszac i pozostanie zerem.

Dziekuje.
Marek_bf
Administrator
Posty: 4419
Rejestracja: czw lut 24, 2005 2:14 am
Kontakt:

Re: wolno działający skrypt

Post autor: Marek_bf »

Łatwo to sprawdzić:

Kod: Zaznacz cały

my_mc.onEnterFrame = function() {
	this._alpha += 10;
	trace(this._alpha);
};
Lub:

Kod: Zaznacz cały

my_mc.onEnterFrame = function() {
	this._alpha -= 10;
	trace(this._alpha);
};
nrb
Nowy
Nowy
Posty: 38
Rejestracja: sob kwie 30, 2005 3:37 pm
Kontakt:

Re: wolno działający skrypt

Post autor: nrb »

no tak, uzywam tej funkcji czsami, bardzo przydatna sprawa.
Ale nie uzylem jej tutaj gdyz bylem przekonany ze wlasciwosc _alhpa nie moze przyjac wartosci ujemnej.

btw. bardzo fajny ten sposob ktory przedstawiles, tylko to juz chyba zahacza o obiektowy actionscript, ktorego delikatnie mowiac nie bardzo znam, choc mysle ze latwo mozna zaimplementowac tutaj obiektowke znana z innych jezykow, np. c++

Wszystko dziala jak nalezy :)
ODPOWIEDZ